home *** CD-ROM | disk | FTP | other *** search
/ FishMarket 1.0 / FishMarket v1.0.iso / fishies / 051-075 / disk_055 / newstartups / astartup.asm next >
Assembly Source File  |  1992-05-06  |  10KB  |  440 lines
  1. * ==========================
  2. * amiga.dev/programs #11, from cscheppner, 10335 chars, Tue Feb 24 17:40:06 1987
  3. * --------------------------
  4. * TITLE:  Astartup.asm --- with 1.2 fixes, handles quotes better
  5.  
  6. ************************************************************************
  7. *
  8. *   Astartup.asm --- C Program Startup/Exit (CLI and WorkBench)
  9. *
  10. *   Modified from the following source by cscheppner
  11. *   (commented out non-functional ToolWindow code)
  12. ************************************************************************
  13. *
  14. *
  15. *
  16. * Source Control:
  17. * --------------
  18. *
  19. * $Header: startup.asm,v 1.1 86/08/25 12:50:07 root Exp $
  20. *
  21. * $Locker: root $
  22. *
  23. * $Log:   startup.asm,v $
  24. * Revision 1.1  86/08/25  12:50:07  root
  25. * Initial revision
  26. *
  27. * Revision 33.6  86/06/12  10:34:36  neil
  28. * changed so any version of dos is OK
  29. * 
  30. * Revision 33.5  86/06/11  19:03:47  neil
  31. * fixed CloseLibrary if open of dos failed
  32. * 
  33. * Revision 33.4  86/06/09  16:48:59  neil
  34. * now processes escapes also
  35. * 
  36. * Revision 33.3  86/06/09  16:18:12  neil
  37. * another checkpoint -- quoted strings now work
  38. * 
  39. * Revision 1.1  85/11/23  13:49:01  neil
  40. * Initial revision
  41. * 
  42. *
  43. ************************************************************************
  44.  
  45.  
  46. ******* Included Files *************************************************
  47.  
  48.    INCLUDE   "exec/types.i"
  49.    INCLUDE "exec/alerts.i"
  50.    INCLUDE "exec/nodes.i"
  51.    INCLUDE "exec/lists.i"
  52.    INCLUDE "exec/ports.i"
  53.    INCLUDE "exec/libraries.i"
  54.    INCLUDE "exec/tasks.i"
  55.    INCLUDE "libraries/dos.i"
  56.    INCLUDE "libraries/dosextens.i"
  57.    INCLUDE "workbench/startup.i"
  58.  
  59.  
  60. ******* Imported *******************************************************
  61.  
  62. xlib   macro
  63.    xref   _LVO\1
  64.    endm
  65.  
  66.    xref   _AbsExecBase
  67.    xref   _Input
  68.    xref   _Output
  69.  
  70.    xref   _main         ; C code entry point
  71.  
  72.    xlib   Alert
  73.    xlib   FindTask
  74.    xlib   Forbid
  75.    xlib   GetMsg
  76.    xlib   OpenLibrary
  77.    xlib   CloseLibrary
  78.    xlib   ReplyMsg
  79.    xlib   Wait
  80.    xlib   WaitPort
  81.  
  82.    xlib   CurrentDir
  83.    xlib   Open
  84.    xlib   Close
  85.  
  86. ******* Exported *******************************************************
  87.  
  88.    xdef   _SysBase
  89.    xdef   _DOSBase
  90.  
  91.    xdef   _errno
  92.    xdef   _stdin
  93.    xdef   _stdout
  94.    xdef   _stderr
  95.  
  96.    xdef   _exit         ; standard C exit function
  97.    xdef   _WBenchMsg
  98.  
  99.  
  100. callsys   macro
  101.    CALLLIB   _LVO\1
  102.    endm
  103.  
  104.  
  105. ************************************************************************
  106. *
  107. *   Standard Program Entry Point
  108. *
  109. ************************************************************************
  110. *
  111. *   main (argc, argv)
  112. *      int  argc;
  113. *      char *argv[]; 
  114. *
  115. ************************************************************************
  116.  
  117. startup:            ; reference for Wack users
  118.       move.l   sp,initialSP   ; initial task stack pointer
  119.       move.l   d0,dosCmdLen
  120.       move.l   a0,dosCmdBuf
  121.  
  122.       ;------ get Exec's library base pointer:
  123.       move.l   _AbsExecBase,a6
  124.       move.l   a6,_SysBase
  125.  
  126.       ;------ get the address of our task
  127.       suba.l   a1,a1
  128.       callsys   FindTask
  129.       move.l   d0,a4
  130.  
  131.       ;------ are we running as a son of Workbench?
  132.       tst.l   pr_CLI(A4)
  133.       beq   fromWorkbench
  134.  
  135. ;=======================================================================
  136. ;====== CLI Startup Code ===============================================
  137. ;=======================================================================
  138. fromCLI:
  139.       ;------   attempt to open DOS library:
  140.       bsr   openDOS
  141.  
  142.       ;------ find command name:
  143.       suba.l   a0,a0
  144.       move.l   pr_CLI(a4),d0
  145.       lsl.l   #2,d0      ; bcpl pointer conversion
  146.       move.l   cli_CommandName(a0,d0.l),d0
  147.       lsl.l   #2,d0      ; bcpl pointer conversion
  148.  
  149.       ;------ create buffer and array:
  150.       movem.l   a2/a3,-(sp)
  151.       lea   argvBuffer,a2
  152.       lea   argvArray,a3
  153.  
  154.       ;------ fetch command name:
  155.       move.l   d0,a0
  156.       moveq.l   #0,d0
  157.       move.b   (a0)+,d0   ; size of command name
  158.       clr.b   0(a0,d0.l)   ; terminate the string
  159.       move.l   a0,(a3)+
  160.  
  161.       ;------   collect parameters:
  162.       move.l   dosCmdLen,d0
  163.       move.l   dosCmdBuf,a0
  164.  
  165.       ;------ null terminate the string, eat trailing garbage
  166.       lea   0(a0,d0.l),a1
  167. stripjunk:
  168.       cmp.b   #' ',-(a1)
  169.  
  170.       ;-- jimm: 8/25/86: per kodiak's recommendation
  171.       ; bls.s   stripjunk
  172.       dbhi   D0,stripjunk
  173.  
  174.       clr.b   1(a1)
  175.  
  176. newarg:
  177.       ;------ skip spaces
  178.       move.b   (a0)+,d1
  179.       beq.s   parmExit
  180.       cmp.b   #' ',d1
  181.       beq.s   newarg
  182.       cmp.b   #9,d1         ; tab
  183.       beq.s   newarg
  184.  
  185.       ;------ push address of the next parameter
  186.       move.l   a2,(a3)+
  187.  
  188.       ;------ process quotes
  189.       cmp.b   #'"',d1
  190.       beq.s   doquote
  191.  
  192.       ;------ copy the parameter in
  193.       move.b   d1,(a2)+
  194.  
  195. nextchar:
  196.       ;------ null termination check
  197.       move.b   (a0)+,d1
  198.       beq.s   parmExit
  199.       cmp.b   #' ',d1
  200.       beq.s   endarg
  201.  
  202.       move.b   d1,(a2)+
  203.       bra.s   nextchar
  204.  
  205. endarg:
  206.       clr.b   (a2)+
  207.       bra.s   newarg
  208.  
  209. doquote:
  210.       ;------ process quoted strings
  211.       move.b   (a0)+,d1
  212.       beq.s   parmExit
  213.       cmp.b   #'"',d1
  214.       beq.s   endarg
  215.  
  216.       ;------ '*' is the BCPL escape character
  217.       cmp.b   #'*',d1
  218.       bne.s   addquotechar
  219.  
  220.       move.b   (a0)+,d1
  221.       cmp.b   #'N',d1
  222.       beq.s   1$
  223.       cmp.b   #'n',d1
  224.       bne.s   2$
  225.  
  226. 1$:
  227.       ;------ got a *N -- turn into a newline
  228.       moveq   #10,d1
  229.       bra.s   addquotechar
  230.  
  231. 2$:
  232.       cmp.b   #'E',d1
  233.       beq.s   3$
  234.       cmp.b   #'e',d1
  235.       bne.s   addquotechar
  236.  
  237. 3$:
  238.       ;------ got a *E -- turn into a escape
  239.       moveq   #27,d1
  240.  
  241. addquotechar:
  242.       move.b   d1,(a2)+
  243.       bra.s   doquote
  244.  
  245. parmExit:
  246.       ;------ all done -- null terminate the baby
  247.       clr.b   (a2)
  248.       clr.l   (a3)
  249.  
  250.       ;------ compute the # of arguments
  251.       move.l   #dosCmdBuf,d0
  252.       sub.l   a3,d0
  253.       not.l   d0
  254.       lsr.l   #2,d0
  255.  
  256.       movem.l   (sp)+,a2/a3
  257.       pea   argvArray
  258.       move.l   d0,-(sp)
  259.  
  260.  
  261. *
  262. *  The above code relies on the end of line containing a control
  263. *  character of any type, i.e. a valid character must not be the
  264. *  last.  This fact is ensured by DOS.
  265. *
  266.       
  267.  
  268.       ;------ get standard input handle:
  269.       jsr   _Input
  270.       move.l   d0,_stdin
  271.  
  272.       ;------ get standard output handle:
  273.       jsr   _Output
  274.       move.l   d0,_stdout
  275.       move.l   d0,_stderr
  276.  
  277.       ;------ call C main entry point
  278.       jsr   _main
  279.  
  280.       ;------ return success code:
  281.       moveq.l   #0,D0
  282.       move.l   initialSP,sp   ; restore stack ptr
  283.       rts
  284.  
  285. ;=======================================================================
  286. ;====== Workbench Startup Code =========================================
  287. ;=======================================================================
  288. fromWorkbench:
  289.       ;------ open the DOS library:
  290.       bsr   openDOS
  291.  
  292.       ;------ we are now set up.  wait for a message from our starter
  293.       bsr   waitmsg
  294.  
  295.       ;------ save the message so we can return it later
  296.       move.l   d0,_WBenchMsg
  297.  
  298.       ;------ push the message on the stack for wbmain
  299.       move.l   d0,-(SP)
  300.       clr.l   -(SP)      indicate: run from Workbench
  301.  
  302.       ;------ get the first argument
  303.       move.l   d0,a2
  304.       move.l   sm_ArgList(a2),d0
  305.       beq.s   docons
  306.  
  307.       ;------ and set the current directory to the same directory
  308.       move.l   _DOSBase,a6
  309.       move.l   d0,a0
  310.       move.l   wa_Lock(a0),d1
  311.       callsys   CurrentDir
  312.  
  313. docons:
  314. * Note: This code commented out for 2 reasons.  WorkBench never passes
  315. *       the ToolWindow ptr in the WBenchMsg, and there is no matching
  316. *       cleanup for this code.   cs
  317.  
  318. *      ;------ get the toolwindow argument
  319. *      move.l   sm_ToolWindow(A2),d1
  320. *      beq.s   domain
  321.  
  322. *      ;------ open up the file
  323. *      move.l   #MODE_OLDFILE,d2
  324. *      callsys   Open
  325.  
  326. *      ;------ set the C input and output descriptors
  327. *      move.l   d0,_stdin
  328. *      move.l   d0,_stdout
  329. *      move.l   d0,_stderr
  330. *      beq.s   domain
  331.  
  332. *      ;------ set the console task (so Open( "*", mode ) will work
  333. *      ;   waitmsg has left the task pointer in A4 for us
  334. *      lsl.l   #2,d0
  335. *      move.l   d0,a0
  336. *      move.l   fh_Type(a0),pr_ConsoleTask(A4)
  337.  
  338. domain:
  339.       jsr   _main
  340.       moveq.l   #0,d0      Successful return code
  341.       bra.s   exit2
  342.  
  343.  
  344. ************************************************************************
  345. *
  346. *   C Program Exit Function
  347. *
  348. ************************************************************************
  349. *
  350. *  Warning: this function really needs to do more than this.
  351. *
  352. ************************************************************************
  353.  
  354. _exit:
  355.       move.l   4(SP),d0   ; extract return code
  356. exit2:
  357.       move.l  initialSP,SP   ; restore stack pointer
  358.       move.l   d0,-(SP)   ; save return code
  359.  
  360.       ;------ close DOS library:
  361.       move.l   _AbsExecBase,A6
  362.       move.l   _DOSBase,d0
  363.       beq.s   1$
  364.       move.l   d0,a1
  365.       callsys   CloseLibrary
  366. 1$:
  367.  
  368.       ;------ if we ran from CLI, skip workbench cleanup:
  369.       tst.l   _WBenchMsg
  370.       beq.s   exitToDOS
  371.  
  372.       ;------ return the startup message to our parent
  373.       ;------   we forbid so workbench can't UnLoadSeg() us
  374.       ;------   before we are done:
  375.       callsys Forbid
  376.       move.l   _WBenchMsg,a1
  377.       callsys   ReplyMsg
  378.  
  379.       ;------ this rts sends us back to DOS:
  380. exitToDOS:
  381.       move.l   (SP)+,d0
  382.       rts
  383.  
  384.  
  385. ;-----------------------------------------------------------------------
  386. noDOS:
  387.       ALERT   (AG_OpenLib!AO_DOSLib)
  388.       moveq.l   #100,d0
  389.       bra.s   exit2
  390.  
  391.  
  392. ;-----------------------------------------------------------------------
  393. ; This routine gets the message that workbench will send to us
  394. ; called with task id in A4
  395.  
  396. waitmsg:
  397.       lea   pr_MsgPort(A4),a0     * our process base
  398.       callsys   WaitPort
  399.       lea   pr_MsgPort(A4),a0     * our process base
  400.       callsys GetMsg
  401.       rts
  402.  
  403. ;-----------------------------------------------------------------------
  404. ;  Open the DOS library:
  405.  
  406. openDOS
  407.       lea   DOSName(pc),A1
  408.       moveq   #0,d0
  409.       callsys OpenLibrary
  410.       move.l   D0,_DOSBase
  411.       beq   noDOS
  412.       rts
  413.  
  414. DOSName      DOSNAME
  415.  
  416. ************************************************************************
  417.  
  418.    DATA
  419.  
  420. ************************************************************************
  421.  
  422. VerRev      dc.w   33,1
  423.  
  424. _SysBase   dc.l   0
  425. _DOSBase   dc.l   0
  426.  
  427. _errno      dc.l   0
  428. _stdin      dc.l   -1
  429. _stdout      dc.l   -1
  430. _stderr      dc.l   -1
  431.  
  432. initialSP   dc.l   0
  433. _WBenchMsg   dc.l   0
  434.  
  435. dosCmdLen   dc.l   0
  436. dosCmdBuf   dc.l   0
  437.  
  438. argvArray   ds.l   32
  439. argvBuffer   ds.b   256
  440.